("f" "Food Tracker" entry (file+datetree "~/org/food.org")
 "* %U %^{Food}"
 :after-finalize (lambda () (unless org-note-abort (my/backup-food-file))))

(defun my/food-show-as-table ()
  "Convert the food.org file into an org table."
  (interactive)
  (let (rows)
    ;; Loop through all headlines in the file
    (with-current-buffer (find-file-noselect "~/org/food.org")
      (org-map-entries
       (lambda ()
         (let ((level (org-current-level))
               (headline (org-get-heading t t t t)))
           ;; Look only at level 4 headings (the actual food items)
           (when (= level 4)
             ;; Regex magic to group each part of the entry
             (string-match "\\[\\([^ ]+\\) [^ ]+ \\([^]]+\\)\\] \\(.*\\)" headline)
             (push (list (match-string 1 headline)
                         (match-string 2 headline)
                         (match-string 3 headline))
                   rows))))))

    ;; Open a new buffer and insert the formatted Org table
    (switch-to-buffer (generate-new-buffer "*Food Table*"))
    (org-mode)
    (insert "|---\n")
    (insert "| Date | Time | Food Item |\n")
    (insert "|---\n")
    (dolist (row (reverse rows))
      (insert (format "| %s | %s | %s |\n" (nth 0 row) (nth 1 row) (nth 2 row))))
    (insert "|---\n")
    (org-table-align)))